globals [ reproductionNoiseSD maxPop  shares donations possibleDonations donationRate color-set turnInc 
          maxDonationRate spread-max established? watched-patch w-donations w-possibleDonations report-time smoothing
          av-rel-tol don-rate pop num-strong-cheat num-weak-cheat]
turtles-own [tag tolerance skill age store strong-cheater?]
patches-own [foodAvailable ]

;;;;;;;;;;;;;;;;;;;;;;;
;;; Setup procedure ;;;
;;;;;;;;;;;;;;;;;;;;;;;
to setup 
  ;; (for this model to work with NetLogo's new plotting features,
  ;; __clear-all-and-reset-ticks should be replaced with clear-all at
  ;; the beginning of your setup procedure and reset-ticks at the end
  ;; of the procedure.)
  clear-all
  set color-set [ red blue lime cyan yellow magenta gray orange violet ]
  set maxPop numFood / foodUsageRate
  ifelse maxAge > 0 
    [set turnInc 360 / maxAge]
    [set turnInc 1]
  set maxDonationRate 1 / numPairings
  set spread-max 0.4
  ask patches [set pcolor grey]
  set watched-patch patch watched-pxcor watched-pycor
  ask watched-patch [set pcolor grey - 1]
  set established? false
  set report-time 0
  set smoothing 0.2
  do-attributes
  do-subpopulations
  do-profile
  reset-ticks
  reset-timer
end

;;;;;;;;;;;;;;;;;
;;; Main loop ;;;
;;;;;;;;;;;;;;;;;
to go
  set report-time smoothing * timer + (1 - smoothing) * report-time
  reset-timer
  if maxTime > 0 and ticks >= maxTime [ stop ]
  ;; if ticks = 0 [repeat initialPop [ generate-agent ]]
  ;; generate initial newcomers
  if count turtles > stopNewThreshold [set established? true]
  if not established? 
    [ask one-of patches [repeat initialNumNew [ generate-agent ]]]
  ;; random newcomers
  if newRate > 0 
    [ repeat (floor (newRate - random-float newRate)) [ ask one-of patches [generate-agent] ] ]
  ;; and any suitable existing agents reproduce
  ask turtles [
    if (min store >= reproduceVal) [
      hatch-agent 
      set store map [ ? - initialFood ] store
    ]
  ]
  
  ;; scatter the food and share it out
  ask patches [
    generate-food
    ask turtles-here [
      let val (item skill store + item skill shares)
      if val > maxRes [ set val maxRes ]
      set store replace-item skill store val
    ]
  ]
  
  ;; then get agents to share where appropriate
  set donations 0
  set possibleDonations 0
  set w-possibleDonations 0
  set w-donations 0
  ask turtles [ do-sharing ]
;;  ifelse count turtles > 0 and possibleDonations > 0
;;    [ set donationRate donations / possibleDonations ]
;;    [ set donationRate 0 ]

  ;; age, consume food and kill off any unfit agents
  ask turtles [
    set age (age + 1)
    set store map [ ? - foodUsageRate ] store
    set size mean store / 20
    if min store <= 0 [die]
    if maxAge > 0 and age > maxAge [ die ]
    right turnInc
  ]
  
  ;; migrate
  ask turtles with [not strong-cheater?] [
    if random-float 1 < prob-migrate [
      ifelse 0 = random 2
        [ set xcor [pxcor] of patch-here + (2 * random 2) - 1  ]
        [ set ycor [pycor] of patch-here + (2 * random 2) - 1  ]
      turtle-display-settings
    ]
  ]
  
  ask turtles with [strong-cheater?] [
    if random-float 1 < prob-cheater-migrate [
      ifelse 0 = random 2
        [ set xcor [pxcor] of patch-here + (2 * random 2) - 1  ]
        [ set ycor [pycor] of patch-here + (2 * random 2) - 1  ]
      turtle-display-settings
    ]
  ]
  
  ;; do displays
  do-attributes
  do-subpopulations
  do-profile
  tick
end

to basic-agent-settings
    set store (n-values numFoodTypes [initialFood])
    set age 0
    set size 0.1
end

to turtle-display-settings
    st
    set heading 0
    set size 0.1
    set color item skill color-set
    setxy pxcor + spread pycor + spread
    ifelse strong-cheater? [set color color - 2 set shape "face sad"] [set shape "default"]
end

;; generate a random agent at a patch
to generate-agent
  sprout 1 [
    basic-agent-settings
    set skill (random numFoodTypes)
    set tolerance (random-float 1) * maxTolerance
    set tag random-float 1
    ifelse random-float 1 < prob-cheater 
      [set strong-cheater? true set tolerance 0] 
      [set strong-cheater? false]
    turtle-display-settings
  ]
end

to introduce-cheaters
  ask watched-patch [
    sprout numb-cheat [
      basic-agent-settings
      set strong-cheater? true
      set skill (random numFoodTypes)
      set tolerance 0
      set tag random-float 1
      turtle-display-settings
    ]
  ]
end

to change-to-cheater
;;  let chosen-patch one-of patches with [count turtles-here >= numb-cheat]
  let numb-turn min list numb-cheat count [turtles-here] of watched-patch
  if numb-turn > 0 [
    ask n-of numb-turn [turtles-here] of watched-patch [
      set strong-cheater? true
      set tolerance 0
      turtle-display-settings
    ]
  ]
end

to-report spread
  report max list (-1 * spread-max) min list spread-max random-normal 0 (spread-max / 3)
end

;; create an offspring, given parent's tolerance, tag and skill
to hatch-agent
  hatch 1 [
    basic-agent-settings
    if random-float 1 < prob-cheater [set strong-cheater? true]
    if probValMutation > 0 [if random-float 1 < probValMutation [
        set tolerance tolerance + random-normal 0 sdValMutation
        set tag tag + random-normal 0 sdValMutation
    ]]
    if sdReproductionNoise > 0 [
      set tolerance tolerance + random-normal 0 sdReproductionNoise
      set tag tag + random-normal 0 sdReproductionNoise
    ]
    if tolerance < 0 [set tolerance 0]
    if tolerance > maxTolerance [set tolerance maxTolerance]
    if tag < 0 [set tag 0]
    if tag > 1 [set tag 1]
    if probSkillMutation > 0 [if random-float 1 < probSkillMutation [
      set skill random numFoodTypes
      set color item skill color-set
    ]]
    if strong-cheater? [set tolerance 0]
    turtle-display-settings
  ]
end

;; maybe turtle display could be... plotted on a val/tolerance axis, with color being skill, 
;; size being number at that val,tol and no direction?

;; scatter the food randomly amongst the food types
;; and calculate the share each agent should get
to generate-food
  set foodAvailable (n-values numFoodTypes [0])
  ;; why 100 here??
  set foodAvailable map [? + random 100] foodAvailable
  let total sum foodAvailable
  ;; just in case 0 is randomly generated numFoodTypes times
  ;; (it did actually happen in testing!)
  ifelse total = 0 [ generate-food ]
  [
   set foodAvailable map [ ? / total * numFood ] foodAvailable
   let pos 0
   set shares []
   repeat numFoodTypes [
     let val count turtles-here with [ skill = pos ]
     ifelse val = 0
       [set shares lput 0 shares]
       [set shares lput ((item pos foodAvailable) / val) shares]
     set pos pos + 1
   ]
 ]
end

;; agent tries random pairings to share any excess resources
to do-sharing
  if count turtles-here > 1 [
    ;; first determine excess
    let unneeded []
    let pos 0
    repeat numFoodTypes [
      let val item pos store - excessVal
      ifelse val > 0
        [set unneeded lput val unneeded]
        [set unneeded lput 0 unneeded]
      set pos pos + 1
    ]
    ;; if agent has nothing to share, don't go further
    if sum unneeded = 0 [ stop ]
    
    ;; select numPairings partners, and keep the ones that
    ;; lie within tolerance
    let partners []
    repeat numPairings [
      let partner one-of other turtles-here
      let diff ([tag] of partner - tag)
      if diff < 0 [ set diff diff * -1 ]
      if diff < tolerance [set partners fput partner partners]
    ]
    
    if patch-here = watched-patch [set w-possibleDonations w-possibleDonations + numPairings]
    set possibleDonations possibleDonations + numPairings
    ;; if there are any suitable partners, dole out the excess
    ;; and delete from own stores
    let num length partners
    if num > 0 [
      set donations donations + length partners
      if patch-here = watched-patch [set w-donations w-donations + length partners]
      let j 0
      repeat numFoodTypes [
        let val item j store
        set store replace-item j store (val - item j unneeded)
        set j j + 1
      ]
      set unneeded map  [? / num] unneeded
      foreach  partners [ ask ? [take-excess unneeded] ]
    ]
  ]
end

;; incorporate donated resources into own stores
to take-excess [ amounts ]
  let pos 0
  repeat numFoodTypes [
    let tmp item pos store + (item pos amounts) * donationBenefit
    if maxRes > 0 and tmp > maxRes [ set tmp maxRes ]
    set store replace-item pos store tmp
    set pos pos + 1
  ]
end

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; VISUALISATION PROCEDURES
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

to do-attributes
  set-current-plot "Agent Attributes" 
  let num (count turtles)
  if num > 0 [
    set-current-plot-pen "av. tolerance" 
    set av-rel-tol (mean [tolerance] of turtles) / maxTolerance
    plot av-rel-tol
  ]
  if count turtles > 0 and possibleDonations > 0 [
    set-current-plot-pen "donation rate"
    set don-rate donations / possibleDonations
    plot don-rate
  ]
  set pop count turtles
  set num-strong-cheat count turtles with [strong-cheater?]
  set num-weak-cheat count turtles with [tolerance = 0]
end

to do-subpopulations
  set-current-plot "Subpopulations"
  set-plot-pen-mode 2
  let pos 0
  repeat numFoodTypes [
    let current-set (([turtles-here] of watched-patch) with [skill = pos])
    set-plot-pen-color item pos color-set
    plot count current-set
    set pos pos + 1
  ]
  set-plot-pen-color black
  plot count ([turtles-here] of watched-patch) with [strong-cheater?]
end

;; plot each agent as a line representing its tag +/- tolerance
;; vertical axis is age, with agents evenly spaced between each 
;; age point so that they can be more clearly seen
to do-profile
  if not profile-on? [stop]
  set-current-plot "Tag Profile"
  clear-plot
  set-plot-x-range 0 1
  ifelse maxAge > 0 
    [set-plot-y-range 0 maxAge]
    [set-plot-y-range 0 360]
  let pos 0
  repeat maxAge [
    let current-set ([turtles-here] of watched-patch) with [age = pos]
    let num count current-set
    if num > 0 [
      set current-set [self] of current-set
      let i 0
      foreach current-set [
        ask ? [
          set-plot-pen-color color
          plot-pen-up
          plotxy (tag - tolerance) age + (i / num)
          plot-pen-down
          plotxy (tag + tolerance) age + (i / num)
          if strong-cheater? [ plot-dot i num]
        ]
        set i i + 1
      ]
    ]
    set pos pos + 1
  ]
end

to plot-dot [i num]
  let dot-sizex 0.0025
  let dot-sizey 0.2
  set-plot-pen-color black
  plotxy tag + dot-sizex age + (i / num) 
  plot-pen-down
  plotxy tag + dot-sizex age + (i / num) + dot-sizey
  plotxy tag - dot-sizex age + (i / num) + dot-sizey
  plotxy tag - dot-sizex age + (i / num) - dot-sizey
  plotxy tag + dot-sizex age + (i / num) - dot-sizey
  plotxy tag + dot-sizex age + (i / num) 
  plot-pen-up
end

to-report safeDiv [nm dn]
  if dn = 0 [report 0]
  report nm / dn
end
@#$#@#$#@
GRAPHICS-WINDOW
6
10
632
657
-1
-1
61.6
1
10
1
1
1
0
1
1
1
0
9
0
9
1
1
1
ticks
30.0

BUTTON
817
308
883
341
NIL
setup
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
953
308
1016
341
go
go
T
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
886
308
949
341
step
go
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

SLIDER
640
49
812
82
numFood
numFood
0
100
50
5
1
NIL
HORIZONTAL

SLIDER
640
126
812
159
maxRes
maxRes
0
10
7
0.1
1
NIL
HORIZONTAL

SLIDER
640
308
812
341
maxAge
maxAge
0
100
45
1
1
NIL
HORIZONTAL

SLIDER
640
89
812
122
initialFood
initialFood
0
10
1
1
1
NIL
HORIZONTAL

SLIDER
640
163
812
196
foodUsageRate
foodUsageRate
0
1
0.17
0.01
1
NIL
HORIZONTAL

SLIDER
640
272
812
305
maxTolerance
maxTolerance
0
1
0.1
0.01
1
NIL
HORIZONTAL

SLIDER
641
201
814
234
reproduceVal
reproduceVal
0
10
4
0.5
1
NIL
HORIZONTAL

SLIDER
640
236
812
269
excessVal
excessVal
0
10
5
0.5
1
NIL
HORIZONTAL

PLOT
819
11
1243
300
Agent Attributes
time
proportion of max value
0.0
1000.0
0.0
1.0
true
true
"" ""
PENS
"av. tolerance" 1.0 0 -13345367 true "" ""
"donation rate" 1.0 0 -10899396 true "" ""

SLIDER
640
345
812
378
numFoodTypes
numFoodTypes
0
9
3
1
1
NIL
HORIZONTAL

SLIDER
641
419
813
452
numPairings
numPairings
0
20
6
1
1
NIL
HORIZONTAL

SLIDER
641
455
813
488
donationBenefit
donationBenefit
0
1
0.9
0.01
1
NIL
HORIZONTAL

PLOT
209
674
487
833
Tag Profile
Tag value
Age
0.0
1.0
0.0
50.0
false
false
"" ""
PENS
"default" 1.0 0 -16777216 true "" ""

SLIDER
641
492
813
525
sdValMutation
sdValMutation
0
0.5
0.2
0.01
1
NIL
HORIZONTAL

SLIDER
642
528
814
561
probValMutation
probValMutation
0
0.5
0.1
0.025
1
NIL
HORIZONTAL

SLIDER
641
11
813
44
maxTime
maxTime
0
100000
10600
100
1
NIL
HORIZONTAL

SLIDER
642
602
814
635
sdReproductionNoise
sdReproductionNoise
0
0.1
0.0050
0.0001
1
NIL
HORIZONTAL

PLOT
492
675
999
837
Subpopulations
NIL
NIL
0.0
10.0
0.0
10.0
true
false
"" ""
PENS
"default" 1.0 0 -16777216 true "" ""

SLIDER
641
564
813
597
probSkillMutation
probSkillMutation
0
0.2
0
0.01
1
NIL
HORIZONTAL

BUTTON
1002
395
1110
428
Intro Cheat
introduce-cheaters
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
1002
431
1111
465
Turn to Cheat
change-to-cheater
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

SLIDER
816
394
988
427
prob-cheater
prob-cheater
0
0.1
0.01
0.001
1
NIL
HORIZONTAL

SLIDER
641
637
813
670
prob-migrate
prob-migrate
0
0.1
0.01
0.001
1
NIL
HORIZONTAL

PLOT
819
469
1242
669
Population
time
Number
0.0
10.0
0.0
10.0
true
false
"" ""
PENS
"all" 1.0 0 -2674135 true "" "plot count turtles"
"cheaters" 1.0 0 -16777216 true "" "plot count turtles with [strong-cheater?]"
"soft" 1.0 0 -7500403 true "" "plot count turtles with [tolerance = 0]"

INPUTBOX
5
698
99
758
watched-pxcor
4
1
0
Number

INPUTBOX
103
697
194
757
watched-pycor
5
1
0
Number

SLIDER
1118
303
1244
336
initialNumNew
initialNumNew
0
10
3
1
1
NIL
HORIZONTAL

SLIDER
1117
340
1245
373
stopNewThreshold
stopNewThreshold
0
500
50
10
1
NIL
HORIZONTAL

SLIDER
639
380
811
413
newRate
newRate
0
10
0
0.1
1
NIL
HORIZONTAL

TEXTBOX
4
676
224
710
Watched Patch (darker patch) ->
13
0.0
1

PLOT
1005
676
1244
838
Patch Sharing Stats
time
Prop Max
0.0
10.0
0.0
1.0
true
false
"" ""
PENS
"donation rate" 1.0 0 -13840069 true "" "ifelse count turtles > 0 and w-possibleDonations > 0 \n     [plot w-donations / w-possibleDonations]\n     [plot 0]"
"av. tolerance" 1.0 0 -13345367 true "" "ask watched-patch [\n  ifelse count turtles-here > 0 \n    [plot (mean [tolerance] of turtles-here) / maxTolerance]\n    [plot 0]\n]"

SLIDER
817
431
989
464
prob-cheater-migrate
prob-cheater-migrate
0
0.1
0.01
0.0025
1
NIL
HORIZONTAL

MONITOR
1125
375
1244
420
Prop Strong Cheat
safeDiv \n  count turtles with [strong-cheater?] \n  count turtles
2
1
11

MONITOR
1125
422
1244
467
Prop Soft Cheat
safeDiv \n  count turtles with [tolerance = 0] \n  count turtles
2
1
11

INPUTBOX
1036
332
1109
392
numb-cheat
5
1
0
Number

SWITCH
92
763
203
796
profile-on?
profile-on?
0
1
-1000

MONITOR
819
348
877
393
Pop
count turtles
0
1
11

MONITOR
883
349
957
394
Secs/Tick
report-time
2
1
11

@#$#@#$#@
## WHAT IS IT?

This model demonstrates how cooperation (sharing) can be achieved through essentially selfish groups. Over time, individual groups of symbiotic relationships develop, and eventually collapse again.  However in the multi-patch version low rates of migration between patches maintains global levels of cooperation.

This is a multi-patch version of the model described in the paper: 

Edmonds, B. (2006) The Emergence of Symbiotic Groups Resulting From Skill-Differentiation and Tags. Journal of Artificial Societies and Social Simulation, 9(1). (http://jasss.soc.surrey.ac.uk/9/1/10.html).  

But also adding in the introduction of "strong cheaters", as defined in:

Shutters, S. T. and Hales, D. (2013) 'Tag-Mediated Altruism is Contingent on How Cheaters Are Defined' Journal of Artificial Societies and Social Simulation 16 (1) 4 <http://jasss.soc.surrey.ac.uk/16/1/4.html>.

## HOW IT WORKS

Each agent can harvest food of a single type, but must have stores of all food types in order to survive. 

Within each patch: agents with similar tag values will share excess resources, giving a means of accessing other resources; agents who gather enough resources reproduce, propagting their strategies (with some mutation); agents who fail to gather sufficient resources die.

The model is made up of a grid of such patches with rates of migration between them, allowing each patch to be 'seeded' from others.  

## HOW TO USE IT

Press setup to initialise the model, then "step" for a single step, or "go" for continuous running.

One can manually introduce batches of strong cheaters (in groups the size set by "numb-cheaters") by pressing the "Intro Cheat" (introduces new cheaters of that number in same patch) or "Turn to Cheat" buttons (changes that number of individuals to cheaters in a patch).

You can only change the number of patches by right-clicking (or ctrl-clicking if a Mac user) on the world display and setting the max-pxcor and max-pycor numbers.

## INITIALISATION

In order to get cooperation started, a number (set in "initialNumNew") of random agents are introduced in a patch until a viable population is establised (a population greater than that set by "stopNewThreshold").  After that no new individuals are added to the model and it is entirely endogenous.

## THINGS TO NOTICE

With only one patch (max-pxcor = 0 and max-pycor = 0) cooperation collapses after a short period of time.  With more patches global cooperation becomes more stable - with a 5x5 set of patches I have never observed it to collapse evn though running it for 50,000 time clicks.

The simulation is resistant to a constant influx of strong cheaters.  The "prob-cheater" slider sets the probability that any new introduced/reproduced individual is a strong cheater.  with a 10x10 patch world it is certainly tolerant to a 1% level of this.

## THE GRAPHS AND VISUALISATIONS

The "Agent Atributes" graph shows the population size, the avereage tollerance of individuals and the rate at which individuals donate to others (as a proportion of the maximum possible).

The "Population" graph shows the total population (red), the proportion of individuals with zero tolerance (grey), and strong cheaters (black).

The Turtle view is another visualisation of the current population.  Each individual is represented by a seperate turtle their:  x-position being their tag, y-position being their tolerance (up to the maximum value), their colour being their skill type, their size representing the average size of their stores, and the direction indicating their age (from veritcally upwards for age 0 and rotating to the right each time interval until almost vertical again at their maximum age).

One selected patch is displayed in greater detail:

The "Tag Profile" is a visualisation of all the individuals that are alive at this instance.  Each individual is represented as a horizontal line, whose centre is at the individual's tag value and whose width is that of its tollerance.  Given enough spare food each individual might donate some of its unneeded food to any other current individuals whose centre (i.e. tag) lies within its width.  The bollour of the individual indicates its skill (i.e. the type of nutrition it can directly harvest).  Clearly to be viable there must be some indivuals of each kind in each viablew tag group.  The horizontal position of the lines indicate the age of the individual.  Individuals of the same age are spread out a little horizontally so they can be seen.

The "Subpopulations" graph shows the number of individuals of each skill type as a seperate line of dots (one colour for each type).  Once a cooperative (i.e. mutally donating) tag group forms you see the population of all types rise and then oscilate with respect of each other until the group eventually collapses again to a situation of non-viability.

"Patch Sharing Stats" shows the average tolerance and donation rate for the patch.


## CREDITS AND REFERENCES

The single patch model was first written by Bruce Edmonds in SDML, then reimplemented by him in Java and then Netlogo by Emma Norling.  This version is a corrected and enhanced version of that NetLofo model.

This model came out of many discussions with David Hales which started when we were trying to understand a model published as:

Riolo, R. L., Cohen, M. D. and Axelrod, R. (2001) Evolution of cooperation without reciprocity. Nature, 411:441-443.

Our analysis and critique of this model was:

Edmonds, B. and Hales, D. (2003) Replication, Replication and Replication - Some Hard Lessons from Model Alignment.  Journal of Artificial Societies and Social Simulation  6(4) (http://jasss.soc.surrey.ac.uk/6/4/11.html)

This model is an attempt to produce a model of tag-based cooperation which did not suffer from the defects of the Riolo et al model, but showed genuiine tag-based cooperation.

It is a multi-patch version of the single patch version that is described in:

Edmonds, B. (2006) The Emergence of Symbiotic Groups Resulting From Skill-Differentiation and Tags. Journal of Artificial Societies and Social Simulation, 9(1). (http://jasss.soc.surrey.ac.uk/9/1/10.html).  

but with the addition of "strong cheaters" as defined in:

Shutters, S. T. and Hales, D. (2013) 'Tag-Mediated Altruism is Contingent on How Cheaters Are Defined' Journal of Artificial Societies and Social Simulation 16 (1) 4 <http://jasss.soc.surrey.ac.uk/16/1/4.html>.

@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 5.0.1
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
<experiments>
  <experiment name="base" repetitions="20" runMetricsEveryStep="true">
    <setup>setup</setup>
    <go>go</go>
    <timeLimit steps="5000"/>
    <metric>count turtles</metric>
    <metric>num-strong-cheat</metric>
    <metric>num-weak-cheat</metric>
    <metric>av-rel-tol</metric>
    <metric>don-rate</metric>
    <enumeratedValueSet variable="maxAge">
      <value value="45"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="initialNumNew">
      <value value="3"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="maxRes">
      <value value="7"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="watched-pxcor">
      <value value="4"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="numb-cheat">
      <value value="5"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="prob-cheater">
      <value value="0.01"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="sdValMutation">
      <value value="0.2"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="maxTolerance">
      <value value="0.1"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="donationBenefit">
      <value value="0.9"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="reproduceVal">
      <value value="4"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="numFoodTypes">
      <value value="3"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="numFood">
      <value value="50"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="numPairings">
      <value value="6"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="excessVal">
      <value value="5"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="prob-cheater-migrate">
      <value value="0.01"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="maxTime">
      <value value="10600"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="probSkillMutation">
      <value value="0"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="probValMutation">
      <value value="0.1"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="sdReproductionNoise">
      <value value="0.0050"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="profile-on?">
      <value value="true"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="newRate">
      <value value="0"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="stopNewThreshold">
      <value value="50"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="foodUsageRate">
      <value value="0.17"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="watched-pycor">
      <value value="5"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="initialFood">
      <value value="1"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="prob-migrate">
      <value value="0.01"/>
    </enumeratedValueSet>
  </experiment>
  <experiment name="vary cheater rate" repetitions="20" runMetricsEveryStep="true">
    <setup>setup</setup>
    <go>go</go>
    <timeLimit steps="5000"/>
    <metric>count turtles</metric>
    <metric>num-strong-cheat</metric>
    <metric>num-weak-cheat</metric>
    <metric>av-rel-tol</metric>
    <metric>don-rate</metric>
    <enumeratedValueSet variable="maxAge">
      <value value="45"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="initialNumNew">
      <value value="3"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="maxRes">
      <value value="7"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="watched-pxcor">
      <value value="4"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="numb-cheat">
      <value value="5"/>
    </enumeratedValueSet>
    <steppedValueSet variable="prob-cheater" first="0" step="0.0025" last="0.03"/>
    <enumeratedValueSet variable="sdValMutation">
      <value value="0.2"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="maxTolerance">
      <value value="0.1"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="donationBenefit">
      <value value="0.9"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="reproduceVal">
      <value value="4"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="numFoodTypes">
      <value value="3"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="numFood">
      <value value="50"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="numPairings">
      <value value="6"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="excessVal">
      <value value="5"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="prob-cheater-migrate">
      <value value="0.01"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="maxTime">
      <value value="10600"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="probSkillMutation">
      <value value="0"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="probValMutation">
      <value value="0.1"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="sdReproductionNoise">
      <value value="0.0050"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="profile-on?">
      <value value="true"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="newRate">
      <value value="0"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="stopNewThreshold">
      <value value="50"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="foodUsageRate">
      <value value="0.17"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="watched-pycor">
      <value value="5"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="initialFood">
      <value value="1"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="prob-migrate">
      <value value="0.01"/>
    </enumeratedValueSet>
  </experiment>
  <experiment name="vary pairings" repetitions="20" runMetricsEveryStep="true">
    <setup>setup</setup>
    <go>go</go>
    <timeLimit steps="5000"/>
    <metric>count turtles</metric>
    <metric>num-strong-cheat</metric>
    <metric>num-weak-cheat</metric>
    <metric>av-rel-tol</metric>
    <metric>don-rate</metric>
    <enumeratedValueSet variable="maxAge">
      <value value="45"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="initialNumNew">
      <value value="3"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="maxRes">
      <value value="7"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="watched-pxcor">
      <value value="4"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="numb-cheat">
      <value value="5"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="prob-cheater">
      <value value="0.01"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="sdValMutation">
      <value value="0.2"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="maxTolerance">
      <value value="0.1"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="donationBenefit">
      <value value="0.9"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="reproduceVal">
      <value value="4"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="numFoodTypes">
      <value value="3"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="numFood">
      <value value="50"/>
    </enumeratedValueSet>
    <steppedValueSet variable="numPairings" first="1" step="1" last="10"/>
    <enumeratedValueSet variable="excessVal">
      <value value="5"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="prob-cheater-migrate">
      <value value="0.01"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="maxTime">
      <value value="10600"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="probSkillMutation">
      <value value="0"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="probValMutation">
      <value value="0.1"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="sdReproductionNoise">
      <value value="0.0050"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="profile-on?">
      <value value="true"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="newRate">
      <value value="0"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="stopNewThreshold">
      <value value="50"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="foodUsageRate">
      <value value="0.17"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="watched-pycor">
      <value value="5"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="initialFood">
      <value value="1"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="prob-migrate">
      <value value="0.01"/>
    </enumeratedValueSet>
  </experiment>
  <experiment name="vary donation benefit" repetitions="20" runMetricsEveryStep="true">
    <setup>setup</setup>
    <go>go</go>
    <timeLimit steps="5000"/>
    <metric>count turtles</metric>
    <metric>num-strong-cheat</metric>
    <metric>num-weak-cheat</metric>
    <metric>av-rel-tol</metric>
    <metric>don-rate</metric>
    <enumeratedValueSet variable="maxAge">
      <value value="45"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="initialNumNew">
      <value value="3"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="maxRes">
      <value value="7"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="watched-pxcor">
      <value value="4"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="numb-cheat">
      <value value="5"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="prob-cheater">
      <value value="0.01"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="sdValMutation">
      <value value="0.2"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="maxTolerance">
      <value value="0.1"/>
    </enumeratedValueSet>
    <steppedValueSet variable="donationBenefit" first="0.5" step="0.1" last="1.1"/>
    <enumeratedValueSet variable="reproduceVal">
      <value value="4"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="numFoodTypes">
      <value value="3"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="numFood">
      <value value="50"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="numPairings">
      <value value="6"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="excessVal">
      <value value="5"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="prob-cheater-migrate">
      <value value="0.01"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="maxTime">
      <value value="10600"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="probSkillMutation">
      <value value="0"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="probValMutation">
      <value value="0.1"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="sdReproductionNoise">
      <value value="0.0050"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="profile-on?">
      <value value="true"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="newRate">
      <value value="0"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="stopNewThreshold">
      <value value="50"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="foodUsageRate">
      <value value="0.17"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="watched-pycor">
      <value value="5"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="initialFood">
      <value value="1"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="prob-migrate">
      <value value="0.01"/>
    </enumeratedValueSet>
  </experiment>
  <experiment name="different sizes w and wo cheaters" repetitions="20" runMetricsEveryStep="true">
    <setup>setup</setup>
    <go>go</go>
    <timeLimit steps="5000"/>
    <metric>count turtles</metric>
    <metric>num-strong-cheat</metric>
    <metric>num-weak-cheat</metric>
    <metric>av-rel-tol</metric>
    <metric>don-rate</metric>
    <enumeratedValueSet variable="maxAge">
      <value value="45"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="initialNumNew">
      <value value="3"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="maxRes">
      <value value="7"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="watched-pxcor">
      <value value="4"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="numb-cheat">
      <value value="5"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="prob-cheater">
      <value value="0"/>
      <value value="0.01"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="sdValMutation">
      <value value="0.2"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="maxTolerance">
      <value value="0.1"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="donationBenefit">
      <value value="0.9"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="reproduceVal">
      <value value="4"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="numFoodTypes">
      <value value="3"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="numFood">
      <value value="50"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="numPairings">
      <value value="6"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="excessVal">
      <value value="5"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="prob-cheater-migrate">
      <value value="0.01"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="maxTime">
      <value value="10600"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="probSkillMutation">
      <value value="0"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="probValMutation">
      <value value="0.1"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="sdReproductionNoise">
      <value value="0.0050"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="profile-on?">
      <value value="true"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="newRate">
      <value value="0"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="stopNewThreshold">
      <value value="50"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="foodUsageRate">
      <value value="0.17"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="watched-pycor">
      <value value="5"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="initialFood">
      <value value="1"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="prob-migrate">
      <value value="0.01"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="max-pxcor">
      <value value="0"/>
      <value value="1"/>
      <value value="2"/>
      <value value="3"/>
      <value value="4"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="max-pycor">
      <value value="0"/>
      <value value="1"/>
      <value value="2"/>
      <value value="3"/>
      <value value="4"/>
    </enumeratedValueSet>
  </experiment>
</experiments>
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 0.0 1.0
0.0 1 1.0 0.0
0.2 0 0.0 1.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180

@#$#@#$#@
0
@#$#@#$#@